Não dê ouvidos a ninguém que lhe diga que a função VALUE no Microsoft Excel está obsoleta. Você provavelmente raramente precisará usá-lo sozinho, mas quando combinado com outras funções, ainda é tão poderoso hoje como quando foi introduzido pela primeira vez em 2007.
A função VALUE: sintaxe e introdução
A função VALUE do Excel possui apenas um argumento:
=VALUE(a)
onde um é o valor armazenado como texto que você deseja converter em um número. Isso pode ser codificado entre aspas duplas ou uma referência a uma célula que contém o valor a ser convertido.
A função VALUE retorna um #VALUE! erro se o texto não puder ser convertido em um número.
Na sua forma mais simples, a função VALUE converte números armazenados como texto em valores numéricos verdadeiros. Isso é particularmente útil se você importou dados de outra fonte e o Excel interpreta erroneamente valores numéricos como texto. Da mesma forma, os números podem ser armazenados como texto se você copiar e colar dados no Excel e o programa não reconhecer valores como números. Em ambos os casos, você pode usar a função VALOR para duplicar os dados em outra célula no formato numérico correto.
A função também pode ser usada para converter outras cadeias de texto, como cadeias de moeda (como US$ 10.000), porcentagens (como 35,7%) e horários (como 14:00), em seus equivalentes numéricos.
No entanto, o Excel geralmente reconhece números armazenados como texto e oferece a opção de convertê-los em valores numéricos sem usar nenhuma função. Como você pode ver na imagem abaixo, o Excel adiciona uma tag verde às células que contêm este erro.
Você sabe que um valor é armazenado como texto quando está alinhado à esquerda em uma célula. Os valores numéricos são alinhados à direita no Excel por padrão.
Se você passar o mouse sobre uma dessas células ou selecionar todas as células afetadas e passar o mouse sobre a seleção, poderá clicar no ícone de erro e escolher “Converter em número” para corrigir o problema.
Neste ponto, você pode estar pensando: “Qual é o sentido da função VALOR se o Excel pode fazer o trabalho pesado para mim?” Na verdade, a função VALOR continua extremamente útil em determinados contextos. Especificamente, mostrarei como isso é útil ao usar funções de texto para organizar e organizar seus números para análise.
Extraindo números de uma string de texto
Quando os números são combinados com letras em uma célula, o Excel os armazena como valores de texto. Por exemplo, os códigos de produto nesta tabela do Excel compreendem uma letra seguida de três dígitos, o que significa que são vistos como texto.
Seu objetivo é extrair os números de cada código de produto como valores numéricos na coluna B para que você possa usá-los em fórmulas futuras.
O primeiro passo é usar a função RIGHT para extrair os números dos códigos:
=RIGHT([@Product],3)
onde [@Product] é a coluna que contém a string da qual você deseja extrair os caracteres, e 3 diz ao Excel para extrair os três caracteres mais à direita.
No entanto, como a função RIGHT é uma função de texto, os números extraídos são armazenados como texto. Isso significa que você não poderá usá-los como valores numéricos em fórmulas. Para corrigir isso, aninhe toda a fórmula dentro da função VALUE:
=VALUE(RIGHT([@Product],3))
Agora, os valores de três dígitos são armazenados como números.
Você pode usar o mesmo princípio com as funções LEFT e MID. Aqui, VALUE e LEFT são usados para extrair os três números no início dos códigos como valores numéricos:
=VALUE(LEFT([@Product],3))
onde [@Product] é a coluna que contém a string original, 3 diz ao Excel para extrair os três caracteres mais à esquerda, e a função VALUE transforma esses caracteres de valores de texto em valores numéricos.
Desta vez, os três caracteres do meio são extraídos usando a função MID, antes de serem convertidos em valores numéricos usando a função VALUE:
=VALUE(MID([@Product],2,3))
onde [@Product] é a coluna que contém a string da qual você deseja extrair um determinado número de caracteres, 2 diz ao Excel para iniciar esta extração no segundo caractere, 3 diz ao Excel para extrair três caracteres do ponto inicial, e a função VALUE transforma os caracteres extraídos em valores numéricos.
Extraindo sequências numéricas delimitadas em linhas separadas
A função VALOR pode economizar muito tempo quando você deseja organizar dados desorganizados e mal estruturados em sua planilha.
Digamos que você tenha recebido esta pasta de trabalho, que contém uma sequência de 1.000 números separados (ou delimitados) por um espaço – também conhecido como sequência delimitada por espaço – na célula A1. Cada número nesta sequência é um valor financeiro que você deseja extrair em células individuais na coluna A para que possa realizar análises relacionadas.
Para fazer isso, primeiro use a função TEXTSPLIT para dividir cada entrada da string em linhas individuais:
=TEXTSPLIT(A1,," ")
onde A1 é a célula que contém a string de texto, o segundo argumento da função TEXTSPLIT (o delimitador de coluna) é omitido porque você deseja o resultado em uma coluna e ” “ informa ao Excel que o delimitador é um espaço. Se os números fossem separados por vírgulas em vez de espaços, você digitaria uma vírgula entre aspas duplas em vez de um espaço.
A função TEXTSPLIT é uma função de matriz dinâmica, o que significa que o resultado se estende da célula onde você digitou a fórmula até as células adjacentes – um comportamento conhecido como derramamento.
Entretanto, como TEXTSPLIT é uma função de texto, o resultado é uma matriz de valores de texto, mesmo que pareçam números. Então, você precisa colocar toda a fórmula dentro de VALUE para converter esses valores em numéricos:
=VALUE(TEXTSPLIT(A1,," "))
Agora que os valores são numéricos, você pode selecionar todas as células e aplicar o formato de número contábil por meio do grupo Número da guia Início na faixa de opções.
Para selecionar todas as células em uma matriz dinâmica, primeiro selecione uma das células e pressione Ctrl+A.
Para converter a matriz dinâmica em valores fixos, selecione as células onde o resultado é derramado, pressione Ctrl+C para copiar seu conteúdo e pressione Ctrl+Shift+V para colá-los como valores.
Finalmente, agora que o resultado não está mais vinculado à célula A1, você pode excluir a sequência de números delimitada por espaço original e formatar os dados recém-apresentados como uma tabela.
Graças a essas etapas rápidas e ao poder da função VALUE, você transformou uma sequência de texto confusa em um conjunto de dados pronto para ser analisado.
Extraindo strings de números de texto delimitados em colunas separadas
No exemplo acima, usamos VALUE com TEXTSPLIT para converter todos os números resultantes em valores numéricos. No entanto, você precisa usar um método ligeiramente diferente para dividir uma sequência delimitada de texto e números enquanto converte os números em valores numéricos verdadeiros.
Suponha que você pediu a um colega de trabalho para usar uma planilha do Excel para verificar o estoque de cada item de roupa, contabilizando itens pequenos, médios e grandes separadamente. No entanto, quando ele compartilhou com você a planilha resultante, você percebe que ele usou vírgulas para separar cada contagem, em vez de colocá-las em colunas individuais.
Como resultado, na célula B2, você precisa reestruturar os dados usando a função TEXTSPLIT e, em seguida, usar a alça de preenchimento para copiar a fórmula para as células restantes:
=TEXTSPLIT(A2,",")
onde A2 é a primeira célula que contém a sequência de números de texto delimitada e “,“ informa ao Excel que o delimitador de coluna é uma vírgula.
Embora, à primeira vista, pareça que você resolveu o problema, os números nas colunas C, D e E estão atualmente armazenados como texto. Você sabe disso porque eles estão alinhados à esquerda.
Como resultado, se você usar esses números em fórmulas, não obterá o resultado esperado.
Para corrigir isso, você pode envolver a função VALUE em torno da fórmula TEXTSPLIT para converter os números em valores numéricos:
=VALUE(TEXTSPLIT(A2,","))
Agora, os totais na coluna F estão corretos e os números nas colunas C a E estão alinhados à direita, o que significa que você os transformou em valores numéricos com sucesso. Porém, observe os erros na coluna B. Isso acontece porque a função VALUE tentou (mas falhou!) converter o texto antes do primeiro delimitador em um número.
Mas não se preocupe – há mais um passo que você pode seguir para corrigir isso. Especificamente, você precisa introduzir a função IFERROR, que retorna um valor personalizado quando uma fórmula gera um erro. Para demonstrar como isso funciona, coloque toda a fórmula dentro de IFERROR e digite x entre aspas duplas para o valor de retorno personalizado:
=IFERROR(VALUE(TEXTSPLIT(A2,",")),"x")
Como você pode ver na captura de tela acima, IFERROR encontrou um erro na coluna B – porque a função VALUE tentou converter os valores de texto da string em números – retornando uma série de x valores como resultado. Então, agora, você precisa dizer ao Excel para retornar o valor do texto original. Para fazer isso, onde você digitou anteriormente xrepita a fórmula TEXTSPLIT que você já usou anteriormente na fórmula:
=IFERROR(VALUE(TEXTSPLIT(A2,",")),TEXTSPLIT(A2,","))
Por fim, como a fórmula acima ainda está vinculada às strings originais na coluna A, copie e cole o resultado como valores (Ctrl+C > Ctrl+Shift+V), converta os dados em uma tabela e exclua os dados da coluna A.
Agora que você entende como funciona a função VALUE, especialmente sua capacidade de trabalhar junto com funções de texto para distinguir números e texto, vá um passo além e use-a ao criar regras personalizadas de validação de dados para células que exigem combinações estritas de letras e números em uma ordem específica.